A Uri object represents an absolute Uniform Resource Identifier (URI) as defined by RFC 2396 and updated by RFC 2373 and RFC 2732. The most commonly used form of URI is the Uniform Resource Locator (URL).

The java.net.URL class cannot be used to parse URIs since it requires the installation of URL stream handlers that may not be available.

The strict parsing mode uses the java.net.URI class to syntactically validate URI strings. The compat mode validate the URI authority and rejects URI fragments, but doesn't perform any additional validation on path and query, other than that which may be implemented in the concrete the Uri subclasses. The legacy mode should not be used unless the application is capable of validating all URI strings before any constructors of this class is invoked.

The format of an absolute URI (see the RFCs mentioned above) is:

absoluteURI   = scheme ":" ( hier_part | opaque_part )

     scheme        = alpha *( alpha | digit | "+" | "-" | "." )

     hier_part     = ( net_path | abs_path ) [ "?" query ]
     opaque_part   = uric_no_slash *uric

     net_path      = "//" authority [ abs_path ]
     abs_path      = "/"  path_segments

     authority     = server | reg_name
     reg_name      = 1*( unreserved | escaped | "$" | "," |
                         ";" | ":" | "@" | "&" | "=" | "+" )
     server        = [ [ userinfo "@" ] hostport ]
     userinfo      = *( unreserved | escaped |
                        ";" | ":" | "&" | "=" | "+" | "$" | "," )

     hostport      = host [ ":" port ]
     host          = hostname | IPv4address | IPv6reference
     port          = *digit

     IPv6reference = "[" IPv6address "]"
     IPv6address   = hexpart [ ":" IPv4address ]
     IPv4address   = 1*3digit "." 1*3digit "." 1*3digit "." 1*3digit
     hexpart       = hexseq | hexseq "::" [ hexseq ] | "::" [ hexseq ]
     hexseq        = hex4 *( ":" hex4)
     hex4          = 1*4hex

     path          = [ abs_path | opaque_part ]
     path_segments = segment *( "/" segment )
     segment       = *pchar *( ";" param )
     param         = *pchar
     pchar         = unreserved | escaped |
                     ":" | "@" | "&" | "=" | "+" | "$" | ","

     query         = *uric

     uric          = reserved | unreserved | escaped
     uric_no_slash = unreserved | escaped | ";" | "?" | ":" | "@" |
                     "&" | "=" | "+" | "$" | ","
     reserved      = ";" | "/" | "?" | ":" | "@" | "&" | "=" | "+" |
                     "$" | "," | "[" | "]"
     unreserved    = alphanum | mark
     mark          = "-" | "_" | "." | "!" | "~" | "*" | "'" | "(" | ")"
     escaped       = "%" hex hex
     unwise        = "{" | "}" | "|" | "\" | "^" | "`"

Currently URIs containing userinfo or reg_name are not supported. The opaque_part of a non-hierarchical URI is treated as if if were a path without a leading slash.